How to change column set of a table on a form programmatically

   // obtaining the data
   Query = New Query;
   Query.Text = QueryText;

   QueryResult = Query.Execute();

   SelectionDetailRecords = QueryResult.Choose();

   QueryResultTableObject = New ValueTable;
   QueryResultTableObject.Clear();
   QueryResultTableObject.Columns.Clear();
   
   For Each Column In QueryResult.Columns Do
      QueryResultTableObject.Columns.Add(Column.Name, Column.ValueType, Column.Name, Column.Width);
   EndDo;

   While SelectionDetailRecords.Next() Do
      Row = QueryResultTableObject.Add();
      FillPropertyValues(Row, SelectionDetailRecords);
   EndDo;

   // removing form items
   QueryResultTableItem = Items.Find("QueryResultTable");
   If QueryResultTableItem <> Undefined Then
      Items.Delete(QueryResultTableItem);
   EndIf;
   
   // creating and filling form attributes
   AttributesToAdd = New Array();
   AttributesToDelete = New Array();
   
   RootAttributes = GetAttributes();
   For Each Attribute In RootAttributes Do
      If Attribute.Path = "" And Attribute.Name = "QueryResultTable" Then
         AttributesToDelete.Add("QueryResultTable");
         Break;
      EndIf;
   EndDo;
   
   QueryResultTableType = New TypeDescription("ValueTable");
   QueryResultTableAttribute = New FormAttribute("QueryResultTable", QueryResultTableType);
   AttributesToAdd.Add(QueryResultTableAttribute);
   For Each Column In QueryResultTableObject.Columns Do
      ColumnAttribute = New FormAttribute(Column.Name, Column.ValueType, "QueryResultTable");
      AttributesToAdd.Add(ColumnAttribute);
   EndDo;
   
   ChangeAttributes(AttributesToAdd, AttributesToDelete);
   ValueToFormAttribute(QueryResultTableObject, "QueryResultTable");
   
   // creating form items
   QueryResultTableItem = Items.Add("QueryResultTable", Type("FormTable"), Items.ResultOutputGroup);
   QueryResultTableItem.DataPath = "QueryResultTable";
   
   For Each Column In QueryResultTableObject.Columns Do
      ColumnItem = Items.Add("QueryResultTable" + Column.Name, 
              Type("FormField"), QueryResultTableItem);
      ColumnItem.Type = FormFieldType.InputField;
      ColumnItem.DataPath = "QueryResultTable." + Column.Name;
   EndDo;